Rheinwerk Design < openbook > Rheinwerk Design - Know-how für Kreative.
Know-how für Kreative

 << zurück
ActionScript 1 und 2 von Sascha Wolter (http://www.saschawolter.de/)
Objektorientierung und Codedesign mit Flash MX 2004
Buch: ActionScript 1 und 2

ActionScript 1 und 2
672 S., mit CD, Referenzkarte, 44,90 Euro
Rheinwerk Design
ISBN 3-89842-221-6
gp Kapitel 15 Movieclips
  gp 15.1 Eigenschaften
  gp 15.2 Fähigkeiten
    gp 15.2.1 Movieclip-Methoden
    gp 15.2.2 Zeichnungsmethoden
  gp 15.3 Selbst definierte Eigenschaften und Fähigkeiten
    gp 15.3.1 Eigenschaften einer Instanz hinzufügen
    gp 15.3.2 Eigenschaften in die Symboldefinition aufnehmen
    gp 15.3.3 Eigenschaften allen Movieclips hinzufügen
    gp 15.3.4 addProperty
    gp 15.3.5 Fähigkeiten als globale Funktion zur Verfügung stellen
    gp 15.3.6 Fähigkeiten einer Instanz hinzufügen
    gp 15.3.7 Fähigkeiten in die Symboldefinition aufnehmen
    gp 15.3.8 Fähigkeiten allen Movieclips hinzufügen
  gp 15.4 Nützliche Erweiterungen
    gp 15.4.1 Positionen auf der Bühne
    gp 15.4.2 Spiegeln
    gp 15.4.3 Bewegen
  gp 15.5 Neue Movieclip-Klassen
    gp 15.5.1 registerClass


Rheinwerk Design - Zum Seitenanfang

15.2 Fähigkeiten  downtop

Movieclips sind von Haus aus nicht nur mit einer ganzen Reihe an Eigenschaften, sondern auch mit zahlreichen Fähigkeiten ausgestattet. Die Fähigkeiten von Movieclips finden sich im ActionScript-Editor in den Ordnern Methoden und Zeichnungsmethoden innerhalb der Kategorie Eingebaute Klassen Film Movieclip. Dabei lassen sich diese Fähigkeiten den folgenden Kategorien zuordnen:

gp  Ereignismethoden
gp  Movieclip-Methoden
gp  Zeichnungsmethoden

Eine Sonderolle haben die Ereignismethoden, mit denen sich das Kapitel »Ereignisse« ab Seite 301 ausführlich beschäftigt. Bleiben noch Movieclip- und Zeichnungsmethoden. Die Movieclip-Methoden beeinflussen die Gestalt einer Movieclip-Instanz, die Zeichnungsmethoden beziehen sich hingegen auf die Gestaltung einer Instanz – also auf deren Inhalt. Dieses Kapitel beschäftigt sich in erster Linie mit den Movieclip-Methoden. Wie Sie in Flash malen, erfahren Sie dann ab Seite 374.

Weitere Fähigkeiten

Movieclips besitzen neben den hier aufgezählten noch weitere Fähigkeiten, die für alle Objekte in Flash gelten und von der Klasse Object geerbt sind.


Rheinwerk Design - Zum Seitenanfang

15.2.1 Movieclip-Methoden  downtop

attachMovie(id:String,name:String,depth:Number,initObject:Object):MovieClip;
gp  Beschreibung: Fügt ein verknüpftes Movieclip-Symbol als neue Instanz ein.
gp  Rückgabewert: Movieclip-Instanz
gp  Aktion: -
gp  Flash Player Version: 5
createEmptyMovieClip(name:String,depth:Number):MovieClip;
gp  Beschreibung: Erstellt eine leere Movieclip-Instanz.
gp  Rückgabewert: Movieclip-Instanz
gp  Aktion: -
gp  Flash Player Version: 6
createTextField(instanceName:String,depth:Number,x:Number,y:Number,width:Number,height:Number):Void;
gp  Beschreibung: Erstellt eine Textfield-Instanz.
gp  Rückgabewert: -
gp  Aktion: -
gp  Flash Player Version: 6
duplicateMovieClip(name:String,depth:Number,initObject:Object):
MovieClip;
gp  Beschreibung: Dupliziert eine Movieclip-Instanz (Klonen).
gp  Rückgabewert: Movieclip-Instanz
gp  Aktion: duplicateMovieClip (seit Flash 4)
gp  Flash Player Version: 5
getBounds(bounds:Object):Object;
gp  Beschreibung: Ermittelt das Begrenzungsrechteck einer Movieclip-Instanz.
gp  Rückgabewert: Objekt mit den Eigenschaften xMin, xMax, yMin und yMax
gp  Aktion: -
gp  Flash Player Version: 5
getBytesLoaded():Number;
gp  Beschreibung: Ermittelt die bereits geladenen Bytes eines Movieclips.
gp  Rückgabewert: Ganzzahl
gp  Aktion: -
gp  Flash Player Version: 5
getBytesTotal():Number;
gp  Beschreibung: Ermittelt die Größe eines Movieclips in Byte.
gp  Rückgabewert: Ganzzahl
gp  Aktion: -
gp  Flash Player Version: 5
getDepth():Number;
gp  Beschreibung: Ermittelt die Tiefe einer Movieclip-Instanz
gp  Rückgabewert: Ganzzahl
gp  Aktion: -
gp  Flash Player Version: 6
getInstanceAtDepth(depth:Number):MovieClip;
gp  Beschreibung: Ermittelt die Instanz in der angegebenen Tiefe.
gp  Rückgabewert: Movieclip-Instanz
gp  Aktion: -
gp  Flash Player Version: 7
getNextHighestDepth():Number;
gp  Beschreibung: Ermittelt die nächste freie Tiefe für eine untergeordnete Movieclip-Instanz in dem Movieclip.
gp  Rückgabewert: Ganzzahl
gp  Aktion: -
gp  Flash Player Version: 7
getSWFVersion():Number;
gp  Beschreibung: Ermittelt die Flash-Version des Movieclips oder der darin liegenden SWF-Datei.
gp  Rückgabewert: Ganzzahl
gp  Aktion: -
gp  Flash Player Version: 7
getTextSnapshot():TextSnapshot;
gp  Beschreibung: Ermittelt den statischen Text in einem Movieclip.
gp  Rückgabewert: TextSnapshot-Instanz
gp  Aktion: -
gp  Flash Player Version: 7
getURL(url:String,window:String,method:String):Void;
gp  Beschreibung: Ruft ein Dokument von einer URL ab.
gp  Rückgabewert: -
gp  Aktion: getURL (seit Flash 2)
gp  Flash Player Version: 5
globalToLocal(pt:Object):Void;
gp  Beschreibung: Konvertiert einen Punkt der Bühne in einen Punkt des Koordinatensystems der Movieclip-Instanz.
gp  Rückgabewert: -
gp  Aktion: -
gp  Flash Player Version: 5
gotoAndPlay(frame:Object):Void; // frame kann String oder Zahl sein.
gp  Beschreibung: Wechselt in das angegebene Bild und spielt die Movieclip-Instanz weiter ab.
gp  Rückgabewert: -
gp  Aktion: gotoAndPlay (seit Flash 2)
gp  Flash Player Version: 5
gotoAndStop(frame:Object):Void; // frame kann String oder Zahl sein.
gp  Beschreibung: Wechselt in das angegebene Bild und stoppt die Movieclip-Instanz.
gp  Rückgabewert: -
gp  Aktion: gotoAndStop (seit Flash 2)
gp  Flash Player Version: 5
hitTest():Boolean; // Die Argumente können entweder target oder x, y, shapeFlag sein.
gp  Beschreibung: Überprüft die Kollisison zweier Objekte bzw. eines Punktes mit einem Objekt.
gp  Rückgabewert: Boolean
gp  Aktion: -
gp  Flash Player Version: 5
loadMovie(url:String,method:String):Void;
gp  Beschreibung: Lädt eine SWF-Datei von der angegebenen URL in die Movieclip-Instanz.
gp  Rückgabewert: -
gp  Aktion: loadMovie (seit Flash 3)
gp  Flash Player Version: 5
loadVariables(url:String,method:String):Void;
gp  Beschreibung: Lädt ein Dokument von der angegebenen URL in die Movieclip-Instanz.
gp  Rückgabewert: -
gp  Aktion: loadVariables (seit Flash 4)
gp  Flash Player Version: 5
localToGlobal(pt:Object):Void;
gp  Beschreibung: Konvertiert einen Punkt aus dem Koordinatensystem der Movieclip-Instanz in einen Punkt auf der Bühne.
gp  Rückgabewert: -
gp  Aktion: -
gp  Flash Player Version: 5
nextFrame():Void;
gp  Beschreibung: Wechselt in das nächste Bild und stoppt die Movieclip-Instanz.
gp  Rückgabewert: -
gp  Aktion: nextFrame (seit Flash 2)
gp  Flash Player Version: 5
play():Void;
gp  Beschreibung: Spielt die Movieclip-Instanz ab.
gp  Rückgabewert: -
gp  Aktion: play (seit Flash 2)
gp  Flash Player Version: 5
prevFrame():Void;
gp  Beschreibung: Wechselt in das vorherige Bild und stoppt die Movieclip-Instanz.
gp  Rückgabewert: -
gp  Aktion: nextFrame (seit Flash 2)
gp  Flash Player Version: 5
removeMovieClip():Void;
gp  Beschreibung: Entfernt die Movieclip-Instanz.
gp  Rückgabewert: -
gp  Aktion: removeMovieClip (seit Flash 4)
gp  Flash Player Version: 5
setMask(mc:Object):Void; // mc darf String oder ein Movieclip sein.
gp  Beschreibung: Maskiert die Movieclip-Instanz
gp  Rückgabewert: -
gp  Aktion: -
gp  Flash Player Version: 6
startDrag(lockCenter:Boolean,left:Number,top:Number,right:Number,bottom:Number):Void;
gp  Beschreibung: Hängt eine Movieclip-Instanz an den Mauszeiger.
gp  Rückgabewert: -
gp  Aktion: startDrag (seit Flash 4)
gp  Flash Player Version: 5
stop():Void;
gp  Beschreibung: Stoppt die Movieclip-Instanz.
gp  Rückgabewert: -
gp  Aktion: stop (seit Flash 2)
gp  Flash Player Version: 5
stopDrag():Void;
gp  Beschreibung: Löst eine Movieclip-Instanz vom Mauszeiger.
gp  Rückgabewert: -
gp  Aktion: stopDrag (seit Flash 4)
gp  Flash Player Version: 5
swapDepths(mc:Object):Void; // mc darf ein String oder eine Zahl sein.
gp  Beschreibung: Verändert die Tiefe (Stapelreihenfolge) einer Movieclip-Instanz.
gp  Rückgabewert: -
gp  Aktion: -
gp  Flash Player Version: 5
unloadMovie():Void;
gp  Beschreibung: Löscht den Inhalt einer Movieclip-Instanz.
gp  Rückgabewert: -
gp  Aktion: unloadMovie (seit Flash 3)
gp  Flash Player Version: 5
valueOf():MovieClip;
gp  Beschreibung: Ermittelt den Wert des Movieclips.
gp  Rückgabewert: MovieClip-Instanz
gp  Aktion: -
gp  Flash Player Version: 5

Rheinwerk Design - Zum Seitenanfang

15.2.2 Zeichnungsmethoden  toptop

Die Zeichnungsmethoden zählen zu den herausragenden Neuigkeiten in Flash MX. Mit diesen ist es seit dieser Version nun endlich möglich, Grafiken zur Laufzeit mit ActionScript zu erzeugen, ohne auf vorgefertigte Elemente zurückgreifen zu müssen. Die Zeichnungsmethoden für Movieclips hat Macromedia innerhalb des ActionScript-Editors unter Zeichnungsmethoden in der Kategorie Eingebaute Klassen Film Movieclip aufgelistet.

linientrick.fla

Aufgrund der vektororientierten Darstellung ist Flash prädestiniert für die Anzeige von dynamischen Grafiken wie zum Beispiel mathematische Graphen oder Kuchendiagramme. Bis Flash MX war dafür jedoch der so genannte Linientrick oder ein Zusatzprodukt wie der mittlerweile eingestellte Macromedia Generator notwendig. Flash MX zeichnet hingegen mit den so genannten Zeichnungsmethoden auch ohne Tricks und Zusatzprodukte. Die neuen Funktionen erweitern darüber hinaus die vielfältigen Einsatzgebiete der Flash-Technologie – egal ob es um die Visualisierung von Börsenkursen oder von technischen Zeichnungen geht, ob dreidimensionale Objekte benötigt werden oder ob Sie einfach nur künstlerisch arbeiten möchten.

Welche Zeichnungsmethoden gibt es?

beginFill(rgb:Number,alpha:Number):Void;

gp  Beschreibung: Beginnt, auf der Bühne eine Füllung zu zeichnen.
gp  Rückgabewert: -
gp  Alternative Aktion: -
gp  Flash Player Version: 6

beginGradientFill(fillType:String,colors:Array,alphas:Array,ratios:Array,matrix:Object):Void;

gp  Beschreibung: Beginnt, auf der Bühne einen Verlauf zu zeichnen.
gp  Rückgabewert: -
gp  Alternative Aktion: -
gp  Flash Player Version: 6

clear():Void

gp  Beschreibung: Entfernt alle mit einer Movieclip-Instanz verbundenen Zeichenbefehle.
gp  Rückgabewert: -
gp  Alternative Aktion: -
gp  Flash Player Version: 6

curveTo(controlX:Number,controlY:Number,anchorX:Number,anchorY: Number):Void;

gp  Beschreibung: Zeichnet eine Kurve mit dem zuletzt verwendeten Strichtyp.
gp  Rückgabewert: -
gp  Alternative Aktion: -
gp  Flash Player Version: 6

endFill():Void;

gp  Beschreibung: Beendet eine mit beginFill oder beginGradientFill begonnene Füllung.
gp  Rückgabewert: -
gp  Alternative Aktion: -
gp  Flash Player Version: 6

lineStyle(thickness:Number,rgb:Number,alpha:Number):Void;

gp  Beschreibung: Definiert den Strichtyp für mit den Methoden lineTo und curveTo erstellte Linien.
gp  Rückgabewert: -
gp  Alternative Aktion: -
gp  Flash Player Version: 6

lineTo(x:Number,y:Number):Void;

gp  Beschreibung: Zeichnet eine Linie mit dem aktuellen Strichtyp.
gp  Rückgabewert: -
gp  Alternative Aktion: -
gp  Flash Player Version: 6

moveTo(x:Number,y:Number):Void;

gp  Beschreibung: Verschiebt die aktuelle Zeichnungsposition an die angegebene Position.
gp  Rückgabewert: -
gp  Alternative Aktion: -
gp  Flash Player Version: 6
Linientrick

Da es bis Flash MX nicht möglich war, Zeichnungen frei zu erstellen, setzen viele Entwickler den Linientrick ein. Dafür wird eine Linie mit einem Winkel von 45 Grad als Movieclip benötigt – der Einfachheit halber vorzugsweise mit einer Höhe und Breite von jeweils 100 Pixeln. Dieser Movieclip dient dann als Baustein für alle weiteren Grafiken. Dabei macht sich der Entwickler die Eigenschaften wie Höhe und Breite zunutze, um die Linie den Erfordernissen anzupassen. Dieser Trick funktioniert natürlich nicht nur mit Linien, sondern auch mit anderen Grafiken. Linien haben aber den Vorteil, dass sie aufgrund ihrer schlichten geometrischen Natur recht einfach zu verwalten sind.

Übrigens verhindert der Strichstil »Haarlinie« weitestgehend die Veränderung (Vergrößerung) der Strichdicke.

Abbildung
Hier klicken, um das Bild zu Vergrößern

lineTo

Abbildung 15.1   Die lineTo-Methode erstellt gerade Striche.

linieTo.fla

Um den Inhalt eines Movieclips frei zu gestalten, sind in der Regel die folgenden Schritte notwendig:

1. 1. Bestimmen Sie die Movieclip-Instanz, die als »Zeichenfläche« dient. Häufig ist es von Vorteil, eine neue Instanz speziell für das Zeichnen zu erzeugen:
       
var myCanvas = _root.createEmptyMovieClip("mcCanvas", 1);
myCanvas._x = Stage.width/2;
myCanvas._y = 50;
2. 2. Sollte bereits etwas in dem Movieclip per ActionScript gezeichnet sein, dann bietet es sich an, dies zu löschen:
       
myCanvas.clear();
3. 3. Bestimmen Sie die Attribute Strichstärke, Strichfarbe und Tranzparenz für die Linien, da die Linie sonst nicht sichtbar ist:
       
myCanvas.lineStyle(0, 0x009933, 100);
4. 4. Zeichnen Sie die Linien wie bei einem Stiftplotter, indem Sie zuerst eine Startposition festlegen, ab der eine oder mehrere Linien gezeichnet werden:
       
myCanvas.moveTo(0, 0);
5. 5. Für gerade Linien verschieben Sie die Position des virtuellen »Stifts« zu gewünschten Positionen, und fertig ist - in diesem Fall - ein Tannenbaum:
       
myCanvas.lineTo(-100, 200);
myCanvas.lineTo(-25, 200);
myCanvas.lineTo(-25, 250);
myCanvas.lineTo(25, 250);
myCanvas.lineTo(25, 200);
myCanvas.lineTo(100, 200);
myCanvas.lineTo(0, 0);
curveTo

Alternativ beherrscht Flash auch die Zeichnung von Kurven mit Hilfe von Anker- und Steuerpunkten. Dabei legt der Ankerpunkt fest, bis wohin die Linie gehen soll, und der Steuerpunkt bestimmt die Krümmung. Die folgenden Zeilen erzeugen somit einen eher geschwungenen Tannenbaum:

Abbildung
Hier klicken, um das Bild zu Vergrößern

Abbildung 15.2   Die curveTo-Methode zeichnet Kurven.

myCanvas.moveTo(0,_0);
curveTo.fla
myCanvas.curveTo(-25,100,–100, 200);
myCanvas.lineTo(-25, 200);
myCanvas.lineTo(-25, 250);
myCanvas.lineTo(25, 250);
myCanvas.lineTo(25, 200);
myCanvas.lineTo(100, 200);
myCanvas.curveTo(25, 100, 0, 0);
Steuerpunkte

Das Verhalten der Anker- und Steuerpunkte ähnelt sehr den aus Illustrationsprogrammen bekannten Bézierkurven. Die Ankerpunkte bestimmen den Start- und Endpunkt. Die Krümmung wird hingegen nicht mit zwei, sondern mit nur einem einzigen Steuerpunkt festgelegt. Dies gilt übrigens für alle Zeichnungen in Flash und ist als quadratische Bézierkurve bekannt (http://www.macromedia.com/support/flash/ts/documents/beziers.htm). Der Vorteil dieser Methode ist eine etwas schnellere Darstellung und weniger Speicherplatzbedarf, da nur drei anstelle von vier Punkten benötigt werden. Das folgende Skript stellt sowohl die Tangenten als auch die resultierende Kurve dar:

Abbildung
Hier klicken, um das Bild zu Vergrößern

Abbildung 15.3   Der Steuerpunkt legt die beiden Tangenten fest, welche die Krümmung einer Kurve bestimmen.

_root.onEnterFrame_=_function()_{
steuerpunkt.fla
   // Definiere Steuerpunkt
   var s = new Object();
   s.x = this._xmouse;
   s.y = this._ymouse;
   // Definiere Ankerpunkte
   var a = new Object();
   a.x = Stage.width/2;
   a.y = Stage.height/3;
   var b = new Object();
   b.x = Stage.width/2;
   b.y = Stage.height*2/3;
   // Lösche Graphik
   this.clear();
   // Setze Linienstil für Verbindungslinien
   this.lineStyle(0, 0x667788, 50);
   // Zeichne Verbindungslinie
   this.moveTo(a.x, a.y);
   this.lineTo(b.x, b.y);
   this.lineTo(s.x, s.y);
   this.lineTo(a.x, a.y);
   // Setze Linienstil für Kurve
   this.lineStyle(2, 0x880000, 50);
   // Zeichne Kurve
   this.moveTo(a.x, a.y);
   this.curveTo(s.x, s.y, b.x, b.y);
};
Formen füllen

Um mit lineTo und curvoTo erstellte Formen nicht nur mit einer Linie zu versehen, sondern auch zu füllen, existieren zwei Möglichkeiten: Formen dürfen mit einer einzelnen Farbe oder mit einem Verlauf versehen werden. Für Verläufe stehen darüber hinaus die Alternativen geradlinig (linear) oder kreisförmig (radial) zur Verfügung.

Abbildung
Hier klicken, um das Bild zu Vergrößern

Abbildung 15.4   Flash beherrscht neben den Strichen auch die Darstellung von Füllungen.

Einfarbige Füllung

Eine einfarbige Füllung leiten Sie mit der Methode beginFill unter Angabe der Farbe und der Transparenz ein. Das Ende legt die Methode endFill fest. Alle Formen, die Sie dazwischen definieren, erhalten automatisch die entsprechende Füllung:

myCanvas.beginFill(0x99CC99, 100);
fill.fla
myCanvas.curveTo(-25, 100, -100, 200);
myCanvas.lineTo(-25, 200);
myCanvas.lineTo(-25, 250);
myCanvas.lineTo(25, 250);
myCanvas.lineTo(25, 200);
myCanvas.lineTo(100, 200);
myCanvas.curveTo(25, 100, 0, 0);
myCanvas.endFill();
Verlaeufe

Etwas schwieriger gestaltet sich der Einsatz von Verläufen. Diese benötigen zuerst einmal die Angabe, ob es sich um einen linearen oder radialen Verlauf handelt:

var fillType="linear";
gradiant Fill.fla

Abbildung
Hier klicken, um das Bild zu Vergrößern

Abbildung 15.5   Sollten einfarbige Füllungen nicht ausreichen, dann bieten sich Verläufe an.

Die Farbwerte und die zugehörigen Transparenzen legen Sie in einem Array ab. Dabei ist zu beachten, dass für jede Farbe in jedem Array genau eine Zelle verwendet wird – d.h. die Elementzahl der Arrays muss übereinstimmen:

var colors=[0x006633, 0x66FF99];
var alphas=[100,100];
Farbverteilung des Verlaufs

Bei der Farbverteilung handelt es sich ebenfalls um ein Array. In diesem legen Sie die Position der Farbe innerhalb des Verlaufs fest – ganz genauso wie im Farbmischer. Der Wert darf zwischen 0 und 255 liegen und gibt die Position im Verlauf von links nach rechts an.

var ratios=[0,255];
Größe und Richtung des Verlaufs

Die größte Herausforderung sind die Angaben für die Größe und Richtung des Verlaufs. Der einfachste Fall ist eine Box aus Position, Höhe, Breite und Drehung:

matrix.matrixType="box";
matrix.x=-100;
matrix.y=0;
matrix.w=200;
matrix.h=500;
matrix.r=0;

Alternativ darf eine Transformationsmatrix gewählt werden, die zur Anpassung von Skalierung, Verschiebung, Drehung und Neigung des Einheitsfarbverlaufs dient – Kenntnisse der Matrizenrechnung sind an dieser Stelle sicherlich von Vorteil, um die Matrix aus drei Spalten und drei Zeilen korrekt einzusetzen. Wen diese Mathematik abschreckt, dem steht ja glücklicherweise die einfachere Box-Version zur Verfügung.

var matrix=new Object();
// Transformationsmatrix
// a b c
// d e f
// g h i
// erste Spalte der Matrix
matrix.a=100;
matrix.d=0;
matrix.g=0;
// zweite Spalte der Matrix
matrix.b=0;
matrix.e=100;
matrix.h=0;
// dritte Spalte der Matrix
matrix.c=0;
matrix.f=0;
matrix.i=100;

Der Rest verhält sich wie bei den einfarbigen Verläufen. D.  h. zuerst wird der Verlauf mit beginGradientFill »gestartet« und dann mit endFill »gestoppt«.

myCanvas.beginGradientFill(fillType, colors, alphas, ratios, matrix);
myCanvas.curveTo(-25, 100, -100, 200);
myCanvas.lineTo(-25, 200);
myCanvas.lineTo(-25, 250);
myCanvas.lineTo(25, 250);
myCanvas.lineTo(25, 200);
myCanvas.lineTo(100, 200);
myCanvas.curveTo(25, 100, 0, 0);
myCanvas.endFill();
Interaktive Objekte

Die Zeichnungsmethoden eignen sich aber nicht nur für statische Objekte. Kombiniert mit den neuen Ereignismethoden entsteht so in nur wenigen Zeilen zum Beispiel ein interaktives Malprogramm:

var target=_root;
malprogramm.fla
target.lineStyle(1, 0x667788, 50);
target.onMouseDown=function () {
   this.moveTo(this._xmouse, this._ymouse);
   this.draw=true;
}
target.onMouseUp=function () {
   this.draw=false;
}
target.onMouseMove=function () {
   if (this.draw) {
      this.lineTo(this._xmouse, this._ymouse);
      updateAfterEvent();
   }
}

Abbildung
Hier klicken, um das Bild zu Vergrößern

Abbildung 15.6   Ein einfaches Malprogramm ist in Flash mit wenigen Zeilen Programmcode schnell erstellt.

Übrigens finden Sie die Beispiele aus diesem Kapitel auch auf der CD-ROM zum Buch. Viel Spaß beim Ausprobieren!

 << zurück
  
  Zum Rheinwerk-Shop
Zum Rheinwerk-Shop: ActionScript 1 und 2
ActionScript 1 und 2
bestellen
 Ihre Meinung?
Wie hat Ihnen das Openbook gefallen?
Ihre Meinung

 Buchtipps
Zum Rheinwerk-Shop: JavaScript






 JavaScript


Zum Rheinwerk-Shop: jQuery






 jQuery


Zum Rheinwerk-Shop: Responsive Webdesign






 Responsive Webdesign


Zum Rheinwerk-Shop: Suchmaschinen-Optimierung






 Suchmaschinen-
 Optimierung


Zum Rheinwerk-Shop: Schrödinger lernt HTML5, CSS3 und JavaScript






 Schrödinger lernt
 HTML5, CSS3
 und JavaScript


 Lieferung
Versandkostenfrei bestellen in Deutschland, Österreich und der Schweiz
InfoInfo





Copyright © Rheinwerk Verlag GmbH 2005
Für Ihren privaten Gebrauch dürfen Sie die Online-Version natürlich ausdrucken. Ansonsten unterliegt das Openbook denselben Bestimmungen, wie die gebundene Ausgabe: Das Werk einschließlich aller seiner Teile ist urheberrechtlich geschützt.
Alle Rechte vorbehalten einschließlich der Vervielfältigung, Übersetzung, Mikroverfilmung sowie Einspeicherung und Verarbeitung in elektronischen Systemen.


Nutzungsbestimmungen | Datenschutz | Impressum

Rheinwerk Verlag GmbH, Rheinwerkallee 4, 53227 Bonn, Tel.: 0228.42150.0, Fax 0228.42150.77, service@rheinwerk-verlag.de

Cookie-Einstellungen ändern